dism 如何用 cmd 指令安裝 windwos

直接上寫好的批次檔，MBR可直接使用
EFI 則需自行切割 EFI 曹位，改一下內容

@echo off
Title dismInstall By Charlotte.HonG& Color 1A

rem 安裝資訊
set EsdFile=chgWin10_1709.wim
set InstallDir=K:\
set EFI_dir=%InstallDir%
set Idx=1

rem 查看資訊
Dism /Get-ImageInfo /ImageFile:%EsdFile%
echo .
echo 即將把 %EsdFile% [%Idx%] 安裝到 %InstallDir%
timeout /t 10

rem 格式化 [謹慎使用怕誤格]
rem format %InstallDir% /q /y

rem 安裝 Windwos
call :TimerStart
Dism /apply-image /imagefile:%EsdFile% /index:%idx% /applydir:%InstallDir%
call :TimerEnd

rem 安裝 BCD
bcdboot %EFI_dir%windows /f ALL /s %EFI_dir%

rem 為 MBR 指定開機磁區[EFI不用]
bootsect /nt60 %EFI_dir%

Rem <================================================
:TimerStart
Rem -------------------------------------------------
rem 取得開始時間
SET A=%TIME%
goto :eof
Rem -------------------------------------------------

Rem <================================================
:TimerEnd
Rem -------------------------------------------------
rem 取得結束時間
SET B=%TIME%

rem 取得時間詳細資料
SET A_HOUR=%A:~0,2%
SET A_MINS=%A:~3,2%
SET A_SECS=%A:~6,2%
SET A_MSEC=%A:~9,2%

SET B_HOUR=%B:~0,2%
SET B_MINS=%B:~3,2%
SET B_SECS=%B:~6,2%
SET B_MSEC=%B:~9,2%

rem FOR debug
rem echo.
rem echo START TIME:%A%
rem echo END   TIME:%B%
rem echo %A_HOUR%:%A_MINS%:%A_SECS%.%A_MSEC%
rem echo %B_HOUR%:%B_MINS%:%B_SECS%.%B_MSEC%

rem 計算耗時
SET /A C_MSEC=B_MSEC-A_MSEC
SET /A C_SECS=B_SECS-A_SECS
SET /A C_MINS=B_MINS-A_MINS
SET /A C_HOUR=B_HOUR-A_HOUR

rem 調整數值
IF %C_MSEC% LSS 0  SET /A C_MSEC+=100 & SET /A C_SECS-=1
IF %C_MSEC% LSS 10 SET C_MSEC=0%C_MSEC%

IF %C_SECS% LSS 0  SET /A C_SECS+=60  & SET /A C_MINS-=1
IF %C_SECS% LSS 10 SET C_SECS=0%C_SECS%

IF %C_MINS% LSS 0  SET /A C_MINS+=60  & SET /A C_HOUR-=1
IF %C_MINS% LSS 10 SET C_MINS=0%C_MINS%

IF %C_HOUR% LSS 0  SET /A C_HOUR+=24
IF %C_HOUR% LSS 10 SET C_HOUR=0%C_HOUR%

echo TimeIs: %C_HOUR%:%C_MINS%:%C_SECS%.%C_MSEC%

ENDLOCAL
goto :eof
Rem -------------------------------------------------

​